-spec close(Socket) -> ok when Socket :: socket().

Closes a UDP socket.

-spec connect(Socket, SockAddr) -> ok | {error, Reason}
                 when
                     Socket :: socket(),
                     SockAddr :: socket:sockaddr_in() | socket:sockaddr_in6(),
                     Reason :: inet:posix().

Connect a UDP socket.

Connecting a UDP socket only means storing the specified (destination) socket address, as specified by SockAddr, so that the system knows where to send data.

When the socket is "connected" it is not necessary to specify the destination address when sending a datagram. That is; send/2 may be used.

It also means that the socket will only receive data from the connected address. Other messages are discarded on arrival by the OS protocol stack.

-spec connect(Socket, Address, Port) -> ok | {error, Reason}
                 when
                     Socket :: socket(),
                     Address :: inet:socket_address() | inet:hostname(),
                     Port :: inet:port_number(),
                     Reason :: inet:posix().

Connect a UDP socket.

See connect/2.

With this function the destination is specified with separate Address and Port arguments where Address may be an IP address or a host name.

-spec controlling_process(Socket, Pid) -> ok | {error, Reason}
                             when
                                 Socket :: socket(),
                                 Pid :: pid(),
                                 Reason :: closed | not_owner | badarg | inet:posix().

Change the controlling process (owner) of a socket.

Assigns a new controlling process Pid to Socket. The controlling process is the process that the socket sends messages to. If this function is called from any other process than the current controlling process, {error, not_owner} is returned.

If the process identified by Pid is not an existing local pid/0, {error, badarg} is returned. {error, badarg} may also be returned in some cases when Socket is closed during the execution of this function.

If the socket is in active mode, this function will transfer any messages from the socket in the mailbox of the caller to the new controlling process.

If any other process is interacting with the socket during the transfer, it may not work correctly and messages may remain in the caller's mailbox. For instance, changing the sockets active mode during the transfer could cause this.

-spec open(Port) -> {ok, Socket} | {error, Reason}
              when Port :: inet:port_number(), Socket :: socket(), Reason :: system_limit | inet:posix().

Equivalent to open(Port, []).

-spec open(Port, Opts) -> {ok, Socket} | {error, Reason}
              when
                  Port :: inet:port_number(),
                  Opts :: [inet:inet_backend() | open_option()],
                  Socket :: socket(),
                  Reason :: system_limit | inet:posix().

Open a UDP socket.

The created socket is bound to the UDP port number Port. If Port == 0, the underlying OS assigns a free (ephemeral) UDP port; use inet:port/1 to retrieve it.

The process that calls this function becomes the Socket's controlling process (socket owner).

UDP socket options

• list - Received Packet is delivered as a list.

• binary - Received Packet is delivered as a binary.

• {ip, Address} - If the local host has many IP addresses, this option specifies which one to use.

• {ifaddr, Address} - Same as {ip, Address}.

  However, if this instead is a socket:sockaddr_in/0 or socket:sockaddr_in6/0 this takes precedence over any value previously set with the ip options. If the ip option comes after the ifaddr option, it may be used to update its corresponding field of the ifaddr option (the addr field).

• {fd, integer() >= 0} - If a socket has somehow been opened without using gen_udp, use this option to pass the file descriptor for it. If Port is not set to 0 and/or {ip, ip_address()} is combined with this option, the fd is bound to the specified interface and port after it is being opened. If these options are not specified, it is assumed that the fd is already bound appropriately.

• inet6 - Sets up the socket for IPv6.

• inet - Sets up the socket for IPv4.

• local - Sets up a Unix Domain Socket. See inet:local_address/0

• {udp_module, module()} - Overrides which callback module is used. Defaults to inet_udp for IPv4 and inet6_udp for IPv6.

• {multicast_if, Address} - Sets the local device for a multicast socket.

• {multicast_loop, true | false} - When true, sent multicast packets are looped back to the local sockets.

• {multicast_ttl, Integer} - Option multicast_ttl changes the time-to-live (TTL) for outgoing multicast datagrams to control the scope of the multicasts.

  Datagrams with a TTL of 1 are not forwarded beyond the local network. Defaults to 1.

• {add_membership, {MultiAddress, InterfaceAddress}} - Joins a multicast group.

• {drop_membership, {MultiAddress, InterfaceAddress}} - Leaves a multicast group.

• option/0 - See inet:setopts/2.

UDP packets are sent with this socket using send(Socket, ...). When UDP packets arrive to the Socket's UDP port, and the socket is in an active mode, the packets are delivered as messages to the controlling process (socket owner):

{udp, Socket, PeerIP, PeerPort, Packet} % Without ancillary data
{udp, Socket, PeerIP, PeerPort, AncData, Packet} % With ancillary data

PeerIP and PeerPort are the address from which Packet was sent. Packet is a list of bytes ([byte/0] if option list is active and a binary/0 if option binaryis active (they are mutually exclusive).

The message contains an AncData field only if any of the socket options recvtos, recvtclass or recvttl are active.

When a socket in {active, N} mode (see inet:setopts/2 for details), transitions to passive ({active, false}) mode (N counts down to 0), the controlling process is notified by a message on this form:

{udp_passive, Socket}

If the OS protocol stack reports an error for the socket, the following message is sent to the controlling process:

{udp_error, Socket, Reason}

Reason is mostly a POSIX Error Code.

If the socket is in passive mode (not in an active mode), received data can be retrieved with therecv/2,3](recv/2) calls. Note that incoming UDP packets that are longer than the receive buffer option specifies can be truncated without warning.

The default value for the receive buffer option is {recbuf, 8192}.

-spec recv(Socket, Length) -> {ok, RecvData} | {error, Reason}
              when
                  Socket :: socket(),
                  Length :: non_neg_integer(),
                  RecvData :: {Address, Port, Packet} | {Address, Port, AncData, Packet},
                  Address :: inet:ip_address() | inet:returned_non_ip_address(),
                  Port :: inet:port_number(),
                  AncData :: inet:ancillary_data(),
                  Packet :: string() | binary(),
                  Reason :: not_owner | inet:posix().

Equivalent to recv(Socket, Length, infinity).

-spec recv(Socket, Length, Timeout) -> {ok, RecvData} | {error, Reason}
              when
                  Socket :: socket(),
                  Length :: non_neg_integer(),
                  Timeout :: timeout(),
                  RecvData :: {Address, Port, Packet} | {Address, Port, AncData, Packet},
                  Address :: inet:ip_address() | inet:returned_non_ip_address(),
                  Port :: inet:port_number(),
                  AncData :: inet:ancillary_data(),
                  Packet :: string() | binary(),
                  Reason :: not_owner | timeout | inet:posix().

Receive a packet from a socket in passive mode.

Timeout specifies a time-out in milliseconds.

If any of the socket options recvtos, recvtclass or recvttl are active, the RecvData tuple contains an AncData field, otherwise it doesn't.

-spec send(Socket, Packet) -> ok | {error, Reason}
              when Socket :: socket(), Packet :: iodata(), Reason :: not_owner | inet:posix().

Send a packet on a connected UDP socket.

To connect a UDP socket, use connect/2 or connect/3.

-spec send(Socket, Destination, Packet) -> ok | {error, Reason}
              when
                  Socket :: socket(),
                  Destination ::
                      {inet:ip_address(), inet:port_number()} |
                      inet:family_address() |
                      socket:sockaddr_in() |
                      socket:sockaddr_in6(),
                  Packet :: iodata(),
                  Reason :: not_owner | inet:posix().

Equivalent to send(Socket, Destination, [], Packet).

-spec send(Socket, Host, Port, Packet) -> ok | {error, Reason}
              when
                  Socket :: socket(),
                  Host :: inet:hostname() | inet:ip_address(),
                  Port :: inet:port_number() | atom(),
                  Packet :: iodata(),
                  Reason :: not_owner | inet:posix();
          (Socket, Destination, AncData, Packet) -> ok | {error, Reason}
              when
                  Socket :: socket(),
                  Destination ::
                      {inet:ip_address(), inet:port_number()} |
                      inet:family_address() |
                      socket:sockaddr_in() |
                      socket:sockaddr_in6(),
                  AncData :: inet:ancillary_data(),
                  Packet :: iodata(),
                  Reason :: not_owner | inet:posix();
          (Socket, Destination, PortZero, Packet) -> ok | {error, Reason}
              when
                  Socket :: socket(),
                  Destination :: {inet:ip_address(), inet:port_number()} | inet:family_address(),
                  PortZero :: inet:port_number(),
                  Packet :: iodata(),
                  Reason :: not_owner | inet:posix().

Send a UDP packet to the specified destination.

With arguments Host and Port

Argument Host can be a hostname or a socket address, and Port can be a port number or a service name atom. These are resolved to a Destination and then this function is equivalent to send(Socket, Destination, [], Packet) just below.

With arguments Destination and AncData (since OTP 22.1)

Sends a packet to the specified Destination with ancillary data AncData.

Note

The ancillary data AncData contains options that for this single message override the default options for the socket, an operation that may not be supported on all platforms, and if so return {error, einval}. Using more than one of an ancillary data item type may also not be supported. AncData =:= [] is always supported.

With arguments Destination and PortZero (since OTP 22.1)

Sends a packet to the specified Destination. Since Destination is a complete address, PortZero is redundant and has to be 0.

This is a legacy clause mostly for Destination = {local, Binary} where PortZero is superfluous. Equivalent to send(Socket, Destination, [], Packet), right above here.

-spec send(Socket, Host, Port, AncData, Packet) -> ok | {error, Reason}
              when
                  Socket :: socket(),
                  Host :: inet:hostname() | inet:ip_address() | inet:local_address(),
                  Port :: inet:port_number() | atom(),
                  AncData :: inet:ancillary_data(),
                  Packet :: iodata(),
                  Reason :: not_owner | inet:posix().

Send a packet to the specified destination, with ancillary data.

Equvalent to send(Socket, Host, Port, Packet) regarding Host and Port and also equivalent to send(Socket, Destination, AncData, Packet) regarding the ancillary data: AncData.